Yes both install and themes were updated, obarun-install had never run in the host ever before, so nothing from the past could have messed with the pkg lists.
On the 2nd try the following day only zenity fails, the reason is the webkit2gtk-4.1 you are not building. When you comment out zenity xfce4 will not work, the dm returns to login, openbox, lxde work fine.
It appears as some xfce4 pkg uses zenity and indirectly webkit2gtk-4.1 that also needs libsystemd.
EFI installation fails both with existing windows and on blank disk with gpt 500MB esp flagged boot partition
66-enable -F tries to find writable /sys which doesn't work on chroot, unless you specifically mount sys rw which risks losing the host system.
It throws an error out, standard, always, I don't see how can you miss it. Whether it works at the end despite the error is a different story which concerns only 66 devs.
Try this:
pkgname=webkit2gtk-4.1
pkgver=2.36.4
pkgrel=3
pkgdesc="Web content engine for GTK w/o systemd"
url="https://webkitgtk.org"
arch=(x86_64)
depends=(cairo fontconfig freetype2 libgcrypt glib2 gtk3 harfbuzz harfbuzz-icu
icu libjpeg libsoup3 libxml2 zlib libpng sqlite atk libwebp at-spi2-core
libegl libgl libgles libwpe wpebackend-fdo libxslt libsecret libtasn1
enchant libx11 libxext libice libxt wayland libnotify hyphen openjpeg2
woff2 bubblewrap libseccomp xdg-dbus-proxy gstreamer
gst-plugins-base-libs libmanette)
makedepends=(cmake ninja gtk-doc python ruby gobject-introspection
wayland-protocols gst-plugins-bad gperf)
optdepends=('geoclue: Geolocation support'
'gst-plugins-good: media decoding'
'gst-plugins-bad: media decoding'
'gst-libav: nonfree media decoding')
# options=(debug) # # uncomment this to produce the debug pkg
source=($url/releases/webkitgtk-$pkgver.tar.xz{,.asc}
7916fda00b347ff263fbfe72c065032d1d9b523c.patch)
prepare() {
cd webkitgtk-$pkgver
# Unbreak LTO
patch -Rp1 -i ../7916fda00b347ff263fbfe72c065032d1d9b523c.patch
}
build() {
# Produce minimal debug info: 4.3 GB of debug data makes the
# build too slow and is too much to package for debuginfod
CFLAGS+=' -g1'
CXXFLAGS+=' -g1'
cmake -S webkitgtk-$pkgver -B build -G Ninja \
-DPORT=GTK \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_INSTALL_LIBEXECDIR=lib \
-DCMAKE_SKIP_RPATH=ON \
-DUSE_SOUP2=OFF \
-DENABLE_GTKDOC=ON \
-DENABLE_MINIBROWSER=ON \
-DENABLE_JOURNALD_LOG=OFF \
-DUSE_JOURNALD=OFF \
-DUSE_JOURNALD_LOG=OFF \
-DUSE_SYSTEMD=OFF
cmake --build build
}
package() {
depends+=(libwpe-1.0.so libWPEBackend-fdo-1.0.so)
provides+=(libjavascriptcoregtk-4.1.so libwebkit2gtk-4.1.so)
DESTDIR="$pkgdir" cmake --install build
rm -r "$pkgdir/usr/bin"
cd webkitgtk-$pkgver
find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
while IFS= read -d $'\0' -r _f; do
echo "# ## $_f # ##"
cat "$_f"
echo
done |
install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# ---- license gpg-key sha256sums ----
license=(custom)
validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3' # Carlos Garcia Campos <cgarcia@ igalia.com>
'5AA3BC334FD7E3369E7C77B291C559DBE4C9123B') # Adrián Pérez de Castro <aperez@ igalia.com>
sha256sums=(b6bebe1f85a479d968c19e44a4704622ef8cef61636ad1b2406b77d16ae2e2a8 # webkitgtk-2.36.4.tar.xz
51f8f88248861c2d7c25658f738fc38be1019bbfbc92ac402094cce6a264994e # webkitgtk-2.36.4.tar.xz.asc
9b1bcb54553274701f7574b1449a29f3a2d569bfbbaaa5d81526270d1c512f3e) # 7916fda00b347ff263fbfe72c065032d1d9b523c.patch