Hi

For those who wan to have a GUI for pacman's official repository (not aur), In KDE there is Discovery which use Packagekit
It is user friendly to search for a package because it embedded screenshot and description but less verbose on what is installed
Personaly i use it only for searching package

You need to recompile packagekit to avoid the dependance of systemd

Here is the PKGBUILD

# $Id$
# Maintainer: Christian Hesse <mail@ eworm.de>
# Contributor: Jonathan Conder <jonno.conder@ gmail.com>
# Modification for obarun : Herve Vidal <h.vidal@ wanadoo.fr>
pkgname='packagekit'
pkgver=1.1.5
pkgrel=2
pkgdesc='A system designed to make installation and updates of packages easier'
arch=('i686' 'x86_64')
url='http://www.packagekit.org/'
license=('GPL')
depends=('dbus-glib' 'pacman>=5.0.0' 'polkit' 'shared-mime-info' 'sqlite')
makedepends=('gobject-introspection' 'gtk-doc' 'intltool'
	'networkmanager' 'bash-completion' 'vala' 'autoconf-archive')
optdepends=('networkmanager: detect connection status'
	'bash-completion: command completion in bash')
backup=('var/lib/PackageKit/transactions.db'
	'etc/PackageKit/alpm.d/pacman.conf'
	'etc/PackageKit/alpm.d/repos.list')
validpgpkeys=(
	'163EB50119225DB3DF8F49EA17ACBA8DFA970E17'	# Richard Hughes <richard@ hughsie.com>
	'EC60AABDF42AAE8FB062640480858FA38F62AF74')	# Kalev Lember <klember@ redhat.com>
source=("https://www.freedesktop.org/software/PackageKit/releases/PackageKit-${pkgver}.tar.xz"{,.asc})
sha256sums=('50f448ced5b460bd79ba0c97e9fe080153eaeecad909eee108284e3f5fc7b70c'
            'SKIP')

build() {
	cd "${srcdir}/PackageKit-${pkgver}"

	./autogen.sh --prefix=/usr \
		--sysconfdir=/etc \
		--localstatedir=/var \
		--libexecdir=/usr/lib/PackageKit \
		--with-dbus-sys=/usr/share/dbus-1/system.d \
		--disable-static \
		--disable-gtk-doc \
		--disable-local \
		--disable-browser-plugin \
		--disable-gstreamer-plugin \
		--disable-gtk-module \
		--disable-command-not-found \
		--disable-cron \
		--disable-dummy \
		--enable-alpm \
		--enable-bash-completion \
		--enable-gtk-module \
		--enable-python3 \
		--disable-systemd \
		--disable-offline-update
	make
}

package() {
	cd "${srcdir}/PackageKit-${pkgver}"

	# install directory with root owner, polkit group and
	# correct permission
	install -d -o root -g 102 -m 750 "${pkgdir}/usr/share/polkit-1/rules.d"

	make DESTDIR="${pkgdir}" install
}

Have fun