refer to this topic : https://forum.obarun.org/viewtopic.php?id=455

Ok found the trouble, hidden system:D dependency. flatpak depend of ostree and ostree have system:D makedepends dependency declaration.
So, you need first to rebuild ostree without system:D support, then install it , then build flatpak
Here is the PKGBUILD for both : 
pkgname=ostree
pkgver=2017.14
pkgrel=2
pkgdesc="Operating system and container binary deployment and upgrades"
url="https://ostree.readthedocs.org/en/latest/"
arch=(x86_64)
license=(GPL)
depends=(glib2 xz zlib libsoup gpgme libarchive fuse2 util-linux mkinitcpio openssl)
makedepends=(e2fsprogs gobject-introspection gtk-doc libxslt git
             python2)
checkdepends=(parallel syslinux gjs cpio elfutils)
_commit=b0f9a298165a99d5621073bd9e1b10f13058e838  # tags/v2017.14^0
source=("git+https://github.com/ostreedev/ostree# commit=$_commit"
        "git+https://github.com/mendsley/bsdiff"
        "git+https://git.gnome.org/browse/libglnx")
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

prepare() {
  cd $pkgname

  git submodule init
  git config --local submodule.bsdiff.url "$srcdir/bsdiff"
  git config --local submodule.libglnx.url "$srcdir/libglnx"
  git submodule update

  find . -name '*.py' -exec sed -i '1s/python$/&2/' {} +

  NOCONFIGURE=1 ./autogen.sh
}

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/^v//;s/-/+/g'
}

build() {
  cd $pkgname
	export gcc=/usr/bin/gcc
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --sbindir=/usr/bin \
    --libexecdir=/usr/lib \
    --with-mkinitcpio \
    --with-openssl \
    --with-builtin-grub2-mkconfig \
    --enable-experimental-api \
    --disable-static \
    --enable-gtk-doc \
    --without-systemdsystemunitdir \ 
    --without-systemdsystemgeneratordir 


  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd $pkgname
  make check || :
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

pkgname=flatpak
pkgver=0.10.2.1
pkgrel=3
pkgdesc="Application deployment framework for desktop apps"
url="http://flatpak.org"
arch=(x86_64)
license=(LGPL2.1)
depends=(dbus glib2 libsoup polkit libxau ostree fuse json-glib libseccomp libarchive
         python bubblewrap appstream-glib)
makedepends=(intltool gobject-introspection gtk-doc git docbook-xsl xmlto)
checkdepends=(valgrind)
install=flatpak.install
_commit=35c9eafc9e10f054872c549a1200450026f36b6b  # tags/0.10.2.1^0
source=("git+https://github.com/flatpak/flatpak# commit=$_commit"
        "git+https://github.com/projectatomic/bubblewrap"
        "git+https://git.gnome.org/browse/libglnx"
        'flathub.flatpakrepo')
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            '3371dd250e61d9e1633630073fefda153cd4426f72f4afa0c3373ae2e8fea03a')
validpgpkeys=('6DD4217456569BA711566AC7F06E8FDE7B45DAAC') # Eric Vidal <eric@ obarun.org>

prepare() {
  cd $pkgname

  git submodule init
  git config --local submodule.bubblewrap.url "$srcdir/bubblewrap"
  git config --local submodule.libglnx.url "$srcdir/libglnx"
  git submodule update

  # https://github.com/flatpak/flatpak/issues/267
  sed -i '/locale\/C\./d' tests/make-test-runtime.sh

  NOCONFIGURE=1 ./autogen.sh
}

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

build() {
  cd $pkgname
  export PYTHONPATH="/usr/share/glib-2.0"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --sbindir=/usr/bin \
    --libexecdir=/usr/lib/$pkgname \
    --disable-static \
    --enable-gtk-doc \
    --with-system-bubblewrap \
    --with-priv-mode=setuid \
    --with-dbus-config-dir=/usr/share/dbus-1/system.d \
    --without-systemduserunitdir \
    --without-systemdsystemunitdir 
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd $pkgname
  # Xattr tests fail on tmpfs
  make -k check || :
}

package() {
  depends+=(xdg-desktop-portal)

  cd $pkgname

  make DESTDIR="$pkgdir" install

  install -Dm644 /dev/stdin "$pkgdir/etc/profile.d/flatpak-bindir.sh" <<END
if [ -d "\$HOME" ] && [ -d "\$HOME/.local/share/flatpak/exports/bin" ]; then
  PATH="\$PATH:\$HOME/.local/share/flatpak/exports/bin"
fi
if [ -d /var/lib/flatpak/exports/bin ]; then
  PATH="\$PATH:/var/lib/flatpak/exports/bin"
fi
END

  install -Dm644 "$srcdir/flathub.flatpakrepo" \
    "$pkgdir/usr/share/flatpak/flathub.flatpakrepo"

  # Fixup mode to match polkit
  install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
}
flatpak uses libostree for desktop application containers. Unlike most of the other systems here, flatpak does not use the "libostree host system" aspects (e.g. bootloader management), just the "git-like hardlink dedup". For example, flatpak supports a per-user OSTree repository.

GNOME Continuous is where OSTree was born - as a high performance continuous delivery/testing system for GNOME.
https://wiki.gnome.org/Projects/GnomeContinuous says that it is not meant for humans, it is meant for Gnome developers!

I knew it, they are aliens!
I checked on Void and flatpak has the following dependencies:
flatpak     Application sandboxing and distribution framework

http://flatpak.org/ 
Version   0.10.2.1_1
Download Size  697KB 
Maintainer  Duncaen <duncaen@ voidlinux.eu> 
Dependencies
appstream-glib>=0.6.13_1
bubblewrap>=0
fuse>=2.8.1_1
glib>=2.18.0_1
glibc>=2.25_1
gpgme>=1.3.0_1
json-glib>=0.12.2_1
libXau>=1.0.4_1
libarchive>=3.1.2_1
libostree>=2017.3_1
libseccomp>=2.0.0_1
libsoup>=2.34.0_1
libxml2>=2.7.0_1
polkit>=0.99_1
libostree has the following dependencies:
libostree
Operating system and container binary deployment and upgrades

URL    https://ostree.readthedocs.io/en/latest/ 
Version    2018.1_1
Download Size    308KB 
Maintainer   Duncaen <duncaen@ voidlinux.eu> 

Dependencies
fuse>=2.8.1_1
glib>=2.18.0_1
glibc>=2.25_1
gpgme>=1.3.0_1
libarchive>=3.1.2_1
libcrypto41>=2.5.3_1
libgpg-error>=1.6_1
liblzma>=5.0.0_1
libmount>=2.18_1
libsoup>=2.34.0_1
zlib>=1.2.3_1

On artix ostree depends on systemd-dummy

Powered by Obarun